EECE 571F= Domain-Specific Languages  
  
This is a page from yet
another great ECE, UBC subject.
[ Home | Assignments | Lectures |
DSL rules | Articles | Resources ]

Ear disease

Some quirky languages: [ Frame-based language | soft-goal rule-based language | formal DSLs ]
A frame-based language. Reference: [Reggia, et.al. 1983].
	
\-------------------------------------------\
\ ****** knowledge base on dizziness ****** \
\-------------------------------------------\

certification:
 "written by:  james  reggia, 1981"
 "testing: *incomplete and untested*"
 "this is an experimental system not for use in practice"%

attachments: definition references management%

quotations:
  htm1 "thorn et al: harrison's textbook of medicine,"
  htm2 "      mcgraw-hill, 1977"
  oh1 "polinsky et al: pharmacologic distinction of different"
  oh2 "     orthostatic hypotension syndromes, neurology,"
  oh3 "     31, 1981, 1-7."
%

\ ****** input attributes ****** \

attributes:

dizziness (val)  [elaboration:
  type(sgl):
    definite rotational sensation [synonyms: vertigo],
    sensation of impending faint [synonyms: syncopal],
    ill-defined light-headedness [synonyms: giddiness],
    loss of balance without head sensation
            [synonyms: imbalance];
  course(sgl):
    acute or subacute persistent deficit lasting
          more than one hour
      [synonyms: acute and persistent],
    one or more clear-cut episodes
      [synonyms: episodic]
      [elaboration:
        episode duration(sgl): minutes, hours, days;
        predominant occurrence [synonyms: occurrence] (sgl):
           only upon assuming or maintaining a vertical
               position [synonyms: orthostatic],
           only upon rapidly changing or assuming a
               particular head position
                  [synonyms: positional],
           only when sneezing or blowing nose,
           only during paroxysm of coughing,
           only while urinating,
           under non-specific or varying conditions
               [synonyms: non-specific]                ],
    gradual onset or slow progression without clear-cut
      episodes [synonyms: chronic]        ].

\ ****** history ****** \

*patient's age [synonyms: age] (int):
   from 20 to 30, from 30 to 40, from 40 to 50,
   from 50 to 65, from 65 to 80, from 80 thru 110 .

*current medications(mlt): anticoagulants, aminoglycosides,
   large amounts of quinine, large amounts of salicylates,
   phenothiazines, antidepressants, antihypertensive agents,
   l-dopa, insulin, tolbutamide or other glucose-lowering
   medications, diuretics, barbiturates or other sedatives.

*past medical history [synonyms: pmh] (mlt):
   diabetes mellitus, alcoholism,
   peptic ulcer disease, hypertension, angina,
   hepatic disease, otitis media,
   seizure disorder, vertebrobasilar tia's.

*history of previous sympathectomy(val).

*history of recent cataract extraction(val).

*recent history (mlt):
  post-op, post-partum,
  prolonged recumbency or immobilization,
  hematemesis or melena or other blood loss,
  fracture or other injury to lower extremity.

*impotence(val).

*urinary incontinence or frequency(val).

*family history (mlt):
  idiopathic hypertrophic subaortic stenosis,
  neurocutaneous syndrome, migraine,
  otosclerosis.

general symptoms occurring with the dizziness
       [synonyms: gensx] (mlt):
   head pain [elaboration:  predominant location(sgl):
     occipital, diffuse,
     intra-oral, periocular, periaural],
   palpitations, persistent shortness of breath, new onset
   of cough, chest pain, preceded by sensation
   of unpleasant odor.

neuro-otological symptoms associated with the dizziness
       [synonyms: neursx] (mlt):
  diplopia [elaboration:
    duration(sgl): transient during dizziness, persistent],
  loss of or blurred vision [elaboration:
    duration(sgl): transient during dizziness, persistent],
  scintillating scotomas,
  focal symptoms referrable to cns
    [synonyms: focsx]
    [definition:
     "any symptoms clearly representing focal brain damage"
     "such as hemiparesis, aphasia, hemisensory deficit,"
     "quadraplegia, etc."]
    [elaboration:
      duration(sgl): transient during dizziness, persistent],
  syncope, hearing loss by history, tinnitus.

\ ****** examination ****** \

temperature(sgl): *normal, elevated.

*hyperemic conjunctiva(val).

ear examination(mlt): inflammation of middle ear,
   *perforated tympanic membrane,
   *occluded external canal.

supraclavicular bruit(val)
   [elaboration: sides(mlt): left, right].

blood pressure examination(mlt):
   *hypertension,
   significant orthostatic hypotension
     [definition:
      "fall in systolic blood pressure below 80 mm hg"
      "or by more than 30 mm hg when patient assumes the"
      "vertical position"],
   more than 20mm hg difference in brachial
             blood pressure
     [elaboration: low side(sgl): left, right].

pulse during dizziness(sgl): marked bradycardia,
   *unremarkable, marked tachycardia.

heart examination [synonyms: corex] (mlt):
  systolic murmur
    [elaboration: predominant location (sgl):
      base, left sternal border, apex],
  pathologically irregular rhythm,
  left ventricular lift,
  thrill at right second interspace.

unilateral delayed or diminished radial pulse(val)
   [elaboration: side(sgl): left, right].

*thrombophlebitis evident in a lower extremity(val).

carotid sinus stimulation for ten seconds(sgl): reproduces dizziness,
   * no significant effect.

hyperventilation for three minutes(sgl): reproduces dizziness,
   * no significant effect.

*pronounced cataracts(val).

pronounced facial or lower extremity erythema after standing(val).

abnormalities on neurological examination [synonyms: neurex] (mlt):
  optic atrophy, papilledema,
  homonymous field cut [elaboration:
    duration(sgl): transient during dizziness, persistent],
  nystagmus [elaboration:
    occurrence(mlt): positional, spontaneous;
    type(mlt): horizontal, vertical, rotatory;
    duration(sgl): transient during dizziness, persistent],
  impaired hearing, peripheral neuropathy, parkinsonism,
  focal cns findings
    [definition:
      "any findings clearly representing focal cns damage"
      "such as hemiparesis, hemisensory deficit, etc."]
    [elaboration:
      onset(sgl): sudden, gradual;
      duration(sgl): transient during dizziness, persistent].

\ ****** inferred attribute ****** \

etiology of dizziness
  [synonyms: diagnosis, dx, assessment, differential, etiology] (mlt):

\ ****** causes of orthostatic hypotension ****** \

secondary to orthostatic hypotension
  [description:
  blood pressure examination = significant orthostatic hypotension ;
  dizziness
    [type= syncopal, giddiness , re ;
     course = episodic [episode duration = minutes , hours ;
         occurrence = orthostatic , re ]];
  neursx = syncope ,
    loss of or blurred vision 
      [duration = transient during dizziness];
  gensx = palpitations   ]

  [elaboration: type (mlt):

  multiple system atrophy
    [synonyms: shy-drager syndrome]
    [references: oh1 oh2 oh3]
    [description:
      age = from 20 to 30 ;
      impotence ; urinary incontinence or frequency;
      focsx  [duration = persistent];
      neurex = nystagmus [occurrence = spontaneous;
                    type = horizontal , vertical ;
                    duration = persistent],
           parkinsonism,
           focal cns findings [onset = gradual;
                         duration = persistent]    ],

  idiopathic orthostatic hypotension
    [references: oh1 oh2 oh3]
    [description:
      impotence ;
      urinary incontinence or frequency  ],

  sympathotonic orthostatic hypotension
    [references: oh1 oh2 oh3]
    [description:
      pulse during dizziness = marked tachycardia  ],

  autonomic neuropathy
    [description:
    age = from 20 to 30 ;
    impotence ; urinary incontinence or frequency;
    past medical history = diabetes mellitus, alcoholism;
    pulse during dizziness = marked tachycardia;
    peripheral neuropathy],

  orthostatic hypotension secondary to phenothiazines
    [description:
    current medications = phenothiazines;
    pulse during dizziness = marked tachycardia;
    parkinsonism ],

  orthostatic hypotension secondary to antidepressants
    [description:
    current medications = antidepressants ;
    pulse during dizziness = marked tachycardia;
    parkinsonism ],

  orthostatic hypotension secondary to l-dopa
    [description:
    current medications = l-dopa ;
    pulse during dizziness = marked tachycardia;
    parkinsonism  ],

  orthostatic hypotension secondary to antihypertensive medications
    [description:
    current medications = antihypertensive agents ;
    pulse during dizziness = marked tachycardia ],

  orthostatic hypotension secondary to diuretics
    [description:
    current medications = diuretics ;
    pulse during dizziness = marked tachycardia  ],

  hyperbradykinism 
    [description:
    pronounced facial or lower extremity erythema after standing ;
    pulse during dizziness = marked tachycardia ],

  orthostatic hypotension secondary to parkinsonism
    [description:
      neurex = parkinsonism ;
      age = from 20 to 40 ;
      current medications = l-dopa  ],

  orthostatic hypotension secondary to previous
       sympathectomy
    [description: history of previous sympathectomy ],

  orthostatic hypotension secondary to prolonged recumbency
    [description:
      prolonged recumbency or immobilization ;
      pulse during dizziness = marked tachycardia  ] ],

\ ****** neurovascular etiologies ****** \

subclavian steel syndrome
  [description:
    dizziness
     [course = acute and persistent,
        episodic
         [episode duration = minutes , hours ;
          occurrence = positional , non-specific,
                         orthostatic             ]];
    head pain 
     [predominant location = occipital , re ];
    neursx = diplopia, loss of or blurred vision,
        focsx, syncope;
    neurex = homonymous field cut,
      nystagmus [type = horizontal, vertical],
      focal cns findings [onset = sudden]                 ]
  [elaboration: side(sgl):
    left subclavian steel syndrome
     [description:
      supraclavicular bruit  [sides = left];
      unilateral delayed or diminished radial pulse 
        [side = left];
      more than 20mm hg difference in brachial blood
        pressure  [low side = left]                      ],
    right subclavian steel syndrome
     [description:
      supraclavicular bruit  [sides = right];
      unilateral delayed or diminished radial pulse 
        [side = right];
      more than 20mm hg difference in brachial blood
        pressure  [low side = right]                      ]   ],

vertebrobasilar transient ischemic attacks
  [description:
    age = from 20 to 40 ;
    pmh = diabetes mellitus , hypertension ,
               vertebrobasilar tia's ;
    dizziness
     [course = acute and persistent,
        episodic [episode duration = minutes, hours;
          occurrence = non-specific , positional ,
                         orthostatic                  ]];
    head pain 
     [predominant location = occipital , re ];
    neursx = diplopia, loss of or blurred vision,
       focsx, syncope ;
    neurex = homonymous field cut,
       nystagmus [type = horizontal, vertical],
       focal cns findings [onset = sudden]                    ],

vertebrobasilar infarction
  [description:
    age = from 20 to 40 ;
    pmh = diabetes mellitus , hypertension ,
               vertebrobasilar tia's ;
    dizziness
     [type = vertigo , imbalance, re ;
      course = acute and persistent];
    head pain 
     [predominant location = occipital , re ];
    neursx = diplopia [duration = persistent],
      loss of or blurred vision [duration = persistent],
      focsx [duration = persistent],
      syncope;
    neurex =
      homonymous field cut [duration = persistent],
      nystagmus [type = horizontal, vertical;
                 duration = persistent],
      focal cns findings
        [onset = sudden; duration = persistent]          ],

basilar migraine
  [references: "lancet, 1, 1961, p. 15"]
  [description:
    age= from 20 to 30 , 30 to 50 , 50 thru 110 ;
    dizziness
     [type= vertigo, re;
      course= episodic [episode duration= minutes, hours, days;
                occurrence = non-specific],
             acute and persistent];
    head pain  [predominant location = occipital , diffuse ,
                     periocular , periaural ];
    neursx = tinnitus,
      diplopia [duration = transient during dizziness],
      loss of or blurred vision [duration = transient during dizziness],
      scintillating scotomas,
      focsx [duration = transient during dizziness],
      syncope ;
    neurex =
      homonymous field cut [duration= transient during dizziness],
      nystagmus [type = horizontal, vertical; occurrence = re;
                 duration = transient during dizziness],
      focal cns findings
       [onset = sudden;
        duration = transient during dizziness];
    family history = migraine        ],

glossopharyngeal neuralgia 
  [description:
    age = from 20 to 24 ;
    dizziness
      [type = syncopal , giddiness ;
       course = episodic [episode duration = minutes;
                           occurrence = non-specific]];
    head pain 
      [predominant location = intra-oral, periaural];
    neursx = loss of or blurred vision
                [duration = transient during dizziness],
             syncope;
    pulse during dizziness = marked bradycardia      ],

vertiginous seizures 
  [description:
    dizziness
     [type = vertigo , re ;
      course = acute and persistent ,
        episodic 
         [episode duration = minutes , hours ;
          occurrence = non-specific]               ];
    pmh = seizure disorder ;
    preceded by sensation of unpleasant odor;
    neursx = loss of or blurred vision ,
      focsx, tinnitus ;
    hyperventilation for three minutes =
      reproduces dizziness ;
    neurex = papilledema , homonymous field
      cut, focal cns findings                        ],

acoustic neuroma or other cerebello-pontine
       angle mass
  [synonyms: acoustic neuroma]
  [description:
    dizziness
     [type = vertigo , imbalance, re ;
      course = chronic , re ];
    head pain
     [predominant location = periaural, occipital,
               diffuse ];
    neursx = diplopia, loss of or blurred vision ,
      focsx [duration = persistent],
      hearing loss by history, tinnitus;
    neurex = nystagmus [duration = persistent],
      impaired hearing ,
      focal cns findings [duration = persistent];
    family history = neurocutaneous syndrome      ],

acute cerebellar hematoma
  [description:
    age = from 20 to 30 ;
    pmh = hypertension ;
    current medications = anticoagulants ;
    dizziness
     [type = imbalance , syncopal , re;
      course = acute and persistent];
    head pain 
      [predominant location = occipital, diffuse,
           periaural   ];
    neursx = diplopia [duration = persistent],
      loss of or blurred vision [duration = persistent],
      focsx [duration = persistent];
    blood pressure examination = hypertension ;
    pulse during dizziness = marked bradycardia ;
    neurex = papilledema ,
      homonymous field cut  [duration = persistent],
      nystagmus
        [type = horizontal, vertical;
         duration = persistent],
      focal cns findings
        [onset = sudden; duration = persistent]           ],

posterior fossa mass lesion
  [description:
    dizziness
     [type = vertigo , imbalance , re ;
      course = chronic , re  ];
    head pain 
     [predominant location = occipital , diffuse ,
         periaural , periocular ];
    neursx = diplopia, loss of or blurred vision,
       syncope , focsx [duration = persistent];
    pulse during dizziness = marked bradycardia ;
    neurex = papilledema , optic atrophy ,
      homonymous field cut  [duration = persistent],
      nystagmus [type = horizontal, vertical;
                 duration = persistent],
      focal cns findings
       [onset = gradual , sudden ;
        duration = persistent           ]              ],

multiple sclerosis 
  [description:
    age = from 20 to 40 , from 50 thru 110 ;
    dizziness
     [type = vertigo , syncopal , re ;
      course = acute and persistent,
        episodic
         [episode duration = hours , days ;
          occurrence = non-specific             ]  ];
    neursx = diplopia [duration = persistent],
      loss of or blurred vision [duration = persistent],
      focsx [duration = persistent], tinnitus ;
    neurex = optic atrophy,
      homonymous field cut  [duration = persistent],
      nystagmus [type = horizontal, vertical;
                 duration = persistent       ],
      focal cns findings
       [onset = sudden , gradual ;
        duration = persistent           ]            ],

\ ****** otologic etiologies ****** \

meniere's disease
  [synonyms: endolymphatic hydrops]
  [description:
    age = from 20 to 30 ;
    dizziness
      [type = vertigo;
       course = acute and persistent,
         episodic [episode duration = minutes , hours ;
                   occurrence = positional , orthostatic ,
                        non-specific ]     ];
    head pain  [predominant location = periaural];
    neursx = hearing loss by history , tinnitus ;
    pulse during dizziness = marked tachycardia ;
    neurex = nystagmus [type = horizontal, rotatory],
             impaired hearing                                ],

acute otitis media
  [description:
    ear examination = inflammation of middle ear ;
    dizziness
      [type = vertigo , imbalance , re ;
       course = acute and persistent];
    head pain  [predominant location = periaural];
    neursx = hearing loss by history, tinnitus;
    temperature = elevated ;
    neurex = impaired hearing                       ],

benign positional vertigo
  [synonyms: cupulolithiasis, benign paroxysmal positional vertigo]
  [description:
    dizziness
      [type = vertigo , giddiness , imbalance ;
       course = episodic
         [episode duration = minutes ;
          occurrence = positional , orthostatic ,
            only when sneezing or blowing nose ,
            only during paroxysm of coughing ] ];
    nystagmus
      [occurrence = positional;
       type = horizontal, rotatory;
       duration = transient during dizziness]           ],

dizziness secondary to occluded external auditory canal
  [description:
    occluded external canal ;
    dizziness
      [type = vertigo , syncopal , re ];
    neursx = hearing loss by history, tinnitus ;
    neurex = impaired hearing                      ],

labyrinthine fistula
  [synonyms: perilabyrinthitis]
  [description:
    dizziness
      [type = vertigo , giddiness , imbalance ;
       course = episodic 
         [episode duration = minutes , hours ;
          occurrence = orthostatic, positional, non-specific,
            only when sneezing or blowing nose,
            only during paroxysm of coughing  ]    ];
    pmh = otitis media ;
    neursx = hearing loss by history, tinnitus;
    ear examination = perforated tympanic membrane ;
    neurex = impaired hearing,
      nystagmus  [type = horizontal, rotatory]            ],

acute vestibulopathy
  [synonyms:
    acute labyrinthitis, vestibular neuronitis, benign recurrent vertigo,
    epidemic vertigo, epidemic labyrinthitis ]
  [definition:
    "this is a 'catch-all' category for a variety of abnormal conditions"
    "with involvement of labyrinthine structures or the peripheral vestibular"
    "nerves (see attached synonyms)."]
  [description:
    dizziness
      [type = vertigo ;
       course = acute and persistent, episodic
           [episode duration = minutes , hours , days ]];
    head pain  [predominant location = periaural];
    neursx = diplopia  [duration = transient during dizziness],
              loss of or blurred vision 
                          [duration = transient during dizziness],
              hearing loss by history , tinnitus;
    nystagmus 
      [type = horizontal, rotatory;
       occurrence = spontaneous , positional ;
       duration = transient during dizziness , persistent]  ],

otosclerosis
  [references:
   "thomas and cody: neurologic perspectives of otosclerosis"
   "     mayo clinic proceedings, 56, 1981, 17-21"            ]
  [description:
    dizziness
     [type = vertigo , imbalance, re ;
      course = episodic
        [episode duration = hours , re;
         occurrence = non-specific , positional,
                      orthostatic ],
        re ];
    family history = otosclerosis ;
    head pain  [predominant location = periaural];
    neursx = hearing loss by history , tinnitus ;
    neurex = nystagmus , impaired hearing       ],

secondary to ototoxic substances
  [description:
    dizziness
     [type = vertigo , re ;
      course = acute and persistent, chronic,
        episodic
         [occurrence = positional , non-specific,
            orthostatic                           ] ];
    neursx = hearing loss by history, tinnitus;
    neurex = nystagmus  [type = horizontal, rotatory],
      impaired hearing                                ]
  [elaboration: type(mlt):
    ototoxicity secondary to aminoglycosides
     [description: current medications = aminoglycosides ],
    ototoxicity secondary to quinine
     [description:
       current medications = large amounts of quinine ],
    ototoxicity secondary to salicylates
     [description:
       current medications = large amounts of salicylates ]  ],

\ ****** cardiac etiologies ****** \

aortic stenosis
  [references: htm1 htm2]
  [description:
    corex =
     systolic murmur 
      [predominant location = base ,
        left sternal border, apex  ],
     left ventricular lift,
     thrill at right second interspace;
    dizziness
     [type = syncopal , giddiness, re ];
    gensx = persistent shortness of breath, chest pain;
    neursx = syncope,
     loss of or blurred vision 
       [duration = transient during dizziness];
    pmh = angina                              ],

idiopathic hypertrophic subaortic stenosis
  [synonyms: ihss, ash, asymmetric septal hypertrophy]
  [references: htm1 htm2]
  [description:
    corex =
      systolic murmur 
       [predominant location = left sternal border ,
          base, apex ],
      left ventricular lift;
    dizziness
     [type = syncopal , giddiness, re ];
    gensx = chest pain,
      persistent shortness of breath;
    neursx = syncope,
      loss of or blurred vision 
        [duration = transient during dizziness];
    pmh = angina ;
    family history =
      idiopathic hypertrophic subaortic stenosis ],

acute myocardial infarction
  [synonyms: mi]
  [references: htm1 htm2]
  [description:
    age = from 20 to 40 ;
    dizziness
     [type = syncopal , giddiness, re;
      course = acute and persistent ,
       episodic 
         [episode duration = minutes, hours;
          occurrence = non-specific ,
             orthostatic, positional    ]  ];
    pmh = angina , diabetes mellitus ;
    gensx = chest pain ,
     persistent shortness of breath;
    neursx = loss of or blurred vision ,
      syncope ;
    corex =
      systolic murmur
       [predominant location = apex , re ];
    temperature = elevated                     ],

cardiac arrhythmias
  [references: htm1 htm2]
  [description:
    dizziness
     [type = syncopal , giddiness, re ;
      course = acute and persistent,
       episodic
        [episode duration = minutes, hours;
         occurrence = non-specific        ]  ];
    gensx = palpitations, chest pain ,
      persistent shortness of breath ;
    neursx = syncope,
      loss of or blurred vision 
        [duration = transient during dizziness]  ]
  [elaboration: type(sgl):
    bradyarrhythmia
     [description:
       pulse during dizziness = marked bradycardia  ],
    tachyarrhythmia
     [description:
       pulse during dizziness = marked tachycardia  ]   ],

\ ****** misc etiologies ****** \

cogan's syndrome 
  [synonyms: non-syphilitic interstitial keratitis]
  [description:
    dizziness
      [type = vertigo ;
       course = acute and persistent , chronic ,
          episodic [episode duration = hours , re ;
                     occurrence = non-specific ]];
    gensx = head pain, new onset of cough,
                persistent shortness of breath;
    neursx = diplopia , hearing loss by history,
                tinnitus ;
    temperature = elevated ;
    hyperemic conjunctiva ;
    neurex = nystagmus [type = horizontal, rotatory],
             impaired hearing                       ],

micturition syncope
  [description:
    dizziness
      [type = syncopal , giddiness ;
       course = episodic [episode duration = minutes;
                          occurrence = only while urinating]];
    neursx = loss of or blurred vision 
                  [duration = transient during dizziness],
              syncope ;
    pulse during dizziness = marked tachycardia           ],

carotid sinus hypersensitivity
  [description:
    dizziness
      [type = syncopal , giddiness , re ;
       course = episodic
         [episode duration = minutes;
          occurrence = positional , non-specific,
                         orthostatic ]];
    neursx = loss of or blurred vision
                [duration = transient during dizziness],
              syncope;
    carotid sinus stimulation for ten seconds
           = reproduces dizziness ;
    pulse during dizziness = marked bradycardia       ],

vasovagal hyperactivity
  [synonyms: vasovagal syncope]
  [description:
    dizziness
      [type = syncopal , giddiness , re ;
       course = episodic
         [episode duration = minutes;
          occurrence = non-specific , orthostatic,
                       positional ]               ];
    age = from 80 thru 110 ;
    neursx = loss of or blurred vision
               [duration = transient during dizziness],
             syncope;
    pulse during dizziness = marked bradycardia ],

hyperventilation syndrome [synonyms: acute anxiety attacks]
  [description:
    age = from 65 thru 110 ;
    dizziness
      [type = giddiness , syncopal , re ;
       course = acute and persistent ,
         episodic [episode duration = minutes , hours ;
                   occurrence = non-specific]              ];
    gensx = palpitations, persistent shortness of breath;
    pulse during dizziness = marked tachycardia;
    hyperventilation for three minutes = reproduces dizziness ],

acute pulmonary thromboembolism
  [synonyms: pe]
  [references: htm1 htm2]
  [description:
    dizziness
      [type = syncopal , giddiness, re ;
       course = acute and persistent];
    gensx = palpitations, persistent shortness of breath,
      new onset of cough, chest pain;
    neursx = syncope ,
      loss of or blurred vision 
        [duration = transient during dizziness];
    temperature = elevated;
    pulse during dizziness = marked tachycardia ;
    thrombophlebitis evident in a lower extremity ;
    recent history = post-op , post-partum ,
      prolonged recumbency or immobilization ,
      fracture or other injury to lower extremity    ],

tussive syncope-like episodes [synonyms: laryngeal vertigo]
  [description:
    dizziness
      [type = syncopal , giddiness ;
       course = episodic [episode duration = minutes;
          occurrence = only during paroxysm of coughing ,
                    only when sneezing or blowing nose  ]];
    new onset of cough;
    neursx = loss of or blurred vision
                [duration = transient during dizziness],
              syncope;
    pulse during dizziness = marked bradycardia             ],

multiple sensory deficits
  [description:
    dizziness
      [type = imbalance , giddiness, re ;
       course = chronic , re          ];
    age = from 20 to 40 , from 65 to 110 ;
    pmh = diabetes mellitus ;
    history of recent cataract extraction ;
    recent history = prolonged recumbency or
            immobilization ;
    neursx = tinnitus ,
       loss of or blurred vision 
          [duration = persistent];
    hyperventilation for three minutes =
            reproduces dizziness ;
    pronounced cataracts ;
    neurex = optic atrophy , impaired hearing ,
      peripheral neuropathy , parkinsonism     ],

hypoglycemia
  [description:
    dizziness
      [type = syncopal , giddiness, re ;
       course = acute and persistent,
         episodic
          [episode duration = minutes, hours;
           occurrence = non-specific         ]];
    current medications = insulin ,
      tolbutamide or other glucose-lowering medications ;
    pmh = alcoholism , hepatic disease ;
    palpitations ;
    neursx = loss of or blurred vision , diplopia ,
      syncope, focsx  [duration=transient during dizziness];
    pulse during dizziness = marked tachycardia;
    neurex = peripheral neuropathy,
       focal cns findings 
        [onset = sudden; duration = transient during dizziness],
       homonymous field cut 
        [duration = transient during dizziness],
       nystagmus 
         [type = horizontal; duration = transient during dizziness] ],

dizziness secondary to barbiturates or other sedatives
  [description:
    dizziness [course = chronic , re ];
    current medications=barbiturates or other sedatives;
    diplopia ;
    nystagmus
     [occurrence = spontaneous;
      type = horizontal , vertical ;
      duration = re]   ] %



actions:

message " "
"this system is designed to help you make decisions about adults"
"who present with the chief complaint of new onset of dizziness. "
"it assumes you are neurologically sophisticated and that a"
"careful history and examination (neurological, otological,"
"cardiac, etc.) were obtained.  this knowledge base will provide"
"you with an assessment of such patients for your consideration."
"special attachments of interest are 'definition', 'references',"
"and 'management'." " "
"this is an experimental system that has not"
"been approved for use in practice" " "
"type 'continue.' to begin or 'display instruction.'"
"if you have not used this system before" .
pause.
mark.
message " "
" ok - let's begin by assuming that your adult patient has"
"presented with the new onset of dizziness.  please answer"
"the following:" .
assert dizziness.
message " "
"now please provide the following basic information . . ." .
askfor age.
askfor current medications.
askfor pmh.
askfor gensx.
askfor neursx.
askfor blood pressure examination.
askfor heart examination.
askfor neurex.
message " "
"now that this basic information has been recorded kms will"
"begin its analysis and perhaps ask you for further information." .
obtain diagnosis.
message " "
"based on the information that you have provided in the context of"
"the currently active knowledge base kms would recommend that you"
"direct your attention to the following etiology/etiologies:" .
display value(diagnosis) %

	

Not © Tim Menzies, 2001
Share and enjoy- information wants to be free.
But if you take anything from this site,
please credit tim@menzies.com.